/*
Twitterのタイムラインを取得して、画面に表示するサンプル

TwitterのAPI経由のアクセスは、1時間に150回という制限がある。
IPによって制限がかかっている。
*/
import java.lang.reflect.*;
import controlP5.*;

// Processing用の画素集ライブラリ
ControlP5 controlP5;

// Twitter ID(API上はscreen_nameという名前)の文字列を指定するテキストフィールド
Textfield screen_names_field;

// バネを模した表示方法（スプリングモデル）
SpringModel sp = null;
String sp_datafile = "SpringModel.txt";
int[] sp_saved_node_edge_count = {0,0};

// Twitterから情報を取得している途中の場合にtrueとして、画面にはその意味の表示を行う。
boolean loading = false;
String error_string = null;
int error_string_displaied_count = -1;

// Twitter APIのラッパークラス
TwitterAPI api;

// Twitterネットワークの隣接行列
AdjacencyMatrix matrix = new AdjacencyMatrix();

// 第一引数の配列から第二引数で指定された数をランダムに抽出した配列を作成する。
String[] selects(String[] ary,int count){
  String[] selected = new String[Math.min(count,ary.length)];
  for(int cnt=0;cnt<ary.length && cnt<selected.length;cnt++){
    int idx = (int)random(ary.length-cnt);
    selected[cnt] = ary[idx];
    if(idx != ary.length-cnt-1){
      arrayCopy(ary,idx+1,ary,idx,ary.length-idx-cnt-1);
    }
  }
  return selected;
}

// indexで指定されるTwitter IDのfollowしている／されているTwitter IDを隣接行列に追加する。
boolean addMatrix(int index,boolean edge_only){
  String[][] ids = new String[2][];
  ids[0] = api.findFollowers(matrix.getNodeName(index));
  if(ids[0]==null){
    return false;
  }
  ids[1] = api.findFriends(matrix.getNodeName(index));
  if(ids[1]==null){
    return false;
  }
  for(int tcnt=0;tcnt<ids.length;tcnt++){
    for(int cnt=0;cnt<ids[tcnt].length;cnt++){
      int idx = matrix.indexOf(ids[tcnt][cnt]);
      if(idx==-1 && edge_only==false){
        idx = matrix.addNode(ids[tcnt][cnt]);
      }
      if(idx!=-1){
        matrix.addEdge(tcnt==0?idx:index,tcnt==0?index:idx);
      }
    }
  }
  return true;
}

// 文字列を特定の文字数に収まるようにする。
String pruning(String s){
  int max_length = 20;
  if(s.length()<=max_length){
    return s;
  }
  return s.substring(0,max_length-2)+" ..";
}

// デバッグ用メソッド
boolean type_test(String[] screen_names)
{
  println("デバック用メソッド");
  return false;
}
// Follower関係のネットワークを作成する。
boolean type_followers(String[] screen_names)
{
  matrix.clear();
  if(screen_names.length < 2){
    error_string = "2つ以上のIDを指定してください。";
    error_string_displaied_count = frameCount+(int)frameRate*4;
    loading = false;
    return false;
  }
  for(int cnt=0;cnt<screen_names.length;cnt++){
    String id = api.screen_name2id(screen_names[cnt]);
    matrix.addNode(id);
  }
  int[] seeds_indexes = {0,matrix.size()};
  for(int gen=0;gen<1;gen++){
    int error_count = 0;
    for(int cnt=seeds_indexes[0];cnt<seeds_indexes[1];cnt++){
      if(false==addMatrix(cnt,false)){
        error_count++;
        // Twitter APIによるデータ取得が連続して失敗した場合には、終了する。
        if(error_count == 3){
          error_string = "Followers, Followingの取得時に失敗しました。";
          error_string_displaied_count = frameCount+(int)frameRate*4;
          loading = false;
          return false;
        }
      }else{
        error_count = 0;
      }
    }
    for(int cnt=seeds_indexes[1];cnt<matrix.size();cnt++){
      double[] rates = matrix.getRates(seeds_indexes,cnt);
      if(rates[0]<0.9 && rates[1]<0.9){
        matrix.deleteNode(cnt);
        cnt--;
      }
    }
    for(int cnt=seeds_indexes[1];cnt<matrix.size();cnt++){
      if(false==addMatrix(cnt,true)){
        error_string = "Followers, Followingの取得時に失敗しました。";
        error_string_displaied_count = frameCount+(int)frameRate*4;
        loading = false;
        return false;
      }
    }
    seeds_indexes[0] = seeds_indexes[1];
    seeds_indexes[1] = matrix.size();
  }
  sp.clear();
  for(int row=0;row<matrix.size();row++){
    for(int col=0;col<matrix.size();col++){
      if(matrix.get(row,col)==1){
        sp.addEdge(api.id2screen_name(matrix.getNodeName(row)),api.id2screen_name(matrix.getNodeName(col)));
      }
    }
  }
  api.saveCache();
  return true;
}
// タイムラインのネットワークを作成する。
boolean type_timeline(String[] screen_names)
{
  if(screen_names.length != 1){
    error_string = "1つのIDを指定してください。";
    error_string_displaied_count = frameCount+(int)frameRate*4;
    loading = false;
    return false;
  }
  Vector<String> statuses = api.findTimeline(this,screen_names[0]);
  if(statuses==null){
    error_string = "タイムラインの取得に失敗しました。";
    error_string_displaied_count = frameCount+(int)frameRate*4;
    loading = false;
    return false;
  }
  sp.clear();
  for(int cnt=1;cnt<statuses.size();cnt++){
    sp.addEdge(pruning(statuses.get(cnt-1)),pruning(statuses.get(cnt)));
  }
  return true;
}
// Twitterの情報を取得する。
// 引数のtwitter_typeには、どのツイッター情報を取得するかを指定する。文字列は、そのままメソッド名になる。
void threadFunc(String twitter_type){
  String[] screen_names = screen_names_field.getText().trim().length()==0?
    new String[0]:screen_names_field.getText().trim().split(",");
  for(int cnt=0;cnt<screen_names.length;cnt++){
    screen_names[cnt] = screen_names[cnt].trim();
  }
  boolean ret=false;
  try{
    Class param[] = {String[].class};
    Method md = getClass().getMethod(twitter_type,param);
    ret = ((Boolean)md.invoke(this,new Object[]{screen_names})).booleanValue();
  }catch(Exception e){
    e.printStackTrace();
  }
//  println("set request "+api.getReqCount()+" times");
  if(ret == true){
    sp.toCirclePosition();
    sp.save("data/"+sp_datafile);
    sp_saved_node_edge_count[0] = sp.getNodeCount();
    sp_saved_node_edge_count[1] = sp.getEdgeCount();
  }
  loading = false;
}
String temp = null;
void setup()
{
  size(800,600);
  // スプリングモデルに画面サイズを教える。
  sp = new SpringModel(width,height,this);
  sp.load((frame==null?getCodeBase().toString():"")+sp_datafile);

  sp.toCirclePosition();
  sp_saved_node_edge_count[0] = sp.getNodeCount();
  sp_saved_node_edge_count[1] = sp.getEdgeCount();
  api = new TwitterAPI();
  
  if(frame!=null){
    controlP5 = new ControlP5(this);
    screen_names_field = controlP5.addTextfield("twitter_ids",20,10,width-140,20);
    screen_names_field.setFocus(true);
    screen_names_field.setAutoClear(false);
    screen_names_field.setText("");
    controlP5.addButton("followers",0,width-110,10,55,20);
    controlP5.addButton("timeline",0,width-45,10,40,20);
  }
}
void draw()
{
  background(0);
  
  if(loading){
    if((frameCount/20) % 2==0){
      fill(255);
      text("loading ...",width/2-32,height/2);
    }
  }else if(error_string!=null){
    fill(255);
    text(error_string,20,height/2);
    if(error_string_displaied_count==-1){
      error_string_displaied_count = frameCount+(int)frameRate*4;
    }else if(error_string_displaied_count<frameCount){
      error_string = null;
      error_string_displaied_count = -1;
    }
  }else if(sp.getNodeCount()!=0){
    // とりあえず、フレームレートでテキストの表示位置を再計算すると負荷がかかりすぎるので
    // フレームレートの3回に1回の計算とする。
    if(frameCount%3==0){
      sp.relax();
    }
    sp.draw();
    
    if(frameCount % 100 == 0){
      if(sp_saved_node_edge_count[0]!=sp.getNodeCount() || sp_saved_node_edge_count[1]!=sp.getEdgeCount()){
        sp.save("data/"+sp_datafile);
        sp_saved_node_edge_count[0] = sp.getNodeCount();
        sp_saved_node_edge_count[1] = sp.getEdgeCount();
      }
    }
  }
}
// followersボタンを押したときに呼ばれるメソッド
public void followers(int theValue){
  connectToTwitter("type_followers");
}
// timelineボタンを押したときに呼ばれるメソッド
public void timeline(int theValue){
  connectToTwitter("type_timeline");
}
// TextfieldのEnterを押したときに呼ばれるメソッド
public void twitter_ids(String theText){
  connectToTwitter("type_followers");
}
// Twitter情報の取得する。どの情報を取得するのかは、引数のtypeに書かれたメソッド名で決定する。
public void connectToTwitter(final String type){
  if(loading==true){
    return;
  }
  loading = true;
  error_string = null;
  error_string_displaied_count = -1;
  (new Thread(){
    public void run(){
      threadFunc(type);
    }
  }).start();
}

// 以下はマウスイベントのハンドラ
// Processingの場合には、ハンドラを使わずにmousePressed変数の値を、drawなどのループしている個所で確認して処理をする方法もある。
// しかしこの場合、そのループのスピードによっては、マウスのイベントを取りそこなうことがある。よってイベント処理の方が良い。
// また、Processingにおいて他のpdeファイルに書かれたプログラムは、すべて1つのjavaファイルになることから、
// 他のpdeファイルでマウスイベントを取るメソッドを書くこともできる。しかし、複数のハンドラを作ってエラーになるなどの
// 面倒な問題を発生する可能性があるため、setup, drawのあるメインのpdeにおいてハンドラを作成し、他のpdeで作成したクラスに
// 発生したイベントを転送するようにしている。
void mousePressed(){
  sp.mousePressed();
}
void mouseReleased(){
  sp.mouseReleased();
}
void mouseDragged(){
  sp.mouseDragged();
}