public class TwitterAPI {
  // Twitter idとscreen_nameの対応に関するキャッシュ
  private HashMap<String,String> cache_id_screen_name = new HashMap<String,String>();
  private HashMap<String,String> cache_screen_name_id = new HashMap<String,String>();
  String cache_filename = "cache_id_screen_name.txt";
  
  // follower, followingに関するキャッシュ
  private HashMap<String,String[]> cache_id_followers = new HashMap<String,String[]>();
  private HashMap<String,String[]> cache_id_friends = new HashMap<String,String[]>();

  // Twitterに送信した要求の数
  private int api_req_count = 0;
  
  public TwitterAPI(){
    loadCache();
  }

  public boolean loadCache(){
    String[] strs = loadStrings(cache_filename);
    if(strs != null){
      for(int cnt=0;cnt<strs.length;cnt++){
        String[] id_sc = strs[cnt].split(",");
        cache_id_screen_name.put(id_sc[0],id_sc[1]);
        cache_screen_name_id.put(id_sc[1],id_sc[0]);
      }
    }
    return true;
  }
  public boolean saveCache(){
    String[] strs = new String[cache_id_screen_name.size()];
    int cnt=0;
    for(Map.Entry entry : cache_id_screen_name.entrySet()){
      strs[cnt++] = entry.getKey()+","+entry.getValue();
    }
    saveStrings("data/"+cache_filename,strs);
    return true;
  }
  public boolean addCache(String id,String screen_name){
    cache_id_screen_name.put(id,screen_name);
    cache_screen_name_id.put(screen_name,id);
    return true;
  }
  public int getReqCount(){
    return api_req_count;
  }
  // Timelineを取得する。
  public Vector<String> findTimeline(PApplet applet,String screen_name){
    Vector<String> statuses = new Vector<String>();
    // TwitterのURL
    String url = "http://twitter.com/statuses/user_timeline/"+screen_name+".xml";
    api_req_count++;
    try{
      XMLElement xml = new XMLElement(applet,url);
      int count = xml.getChildCount();
      String old_text = null;
      for(int cnt=0;cnt<xml.getChildCount();cnt++){
        statuses.add(xml.getChild(cnt).getChild("text").getContent());
      }
    }catch(Exception e){
      return null;
    }
    return statuses;
  }  
  public String[] findFollowers(String user_id){
    String[] ids = cache_id_followers.get(user_id);
    if(ids == null){
      ids = findIds(user_id,"followers");
      if(ids != null){
        cache_id_followers.put(user_id,ids);
      }
    }
    return ids;
  }
  public String[] findFriends(String user_id){
    String[] ids = cache_id_friends.get(user_id);
    if(ids == null){
      ids = findIds(user_id,"friends");
      if(ids != null){
        cache_id_friends.put(user_id,ids);
      }
    }
    return ids;
  }
  private String[] findIds(String user_id,String api_name){
    JSON json = new JSON();
    api_req_count++;
    try{Thread.sleep(10);}catch(InterruptedException e){}
println("getting - "+"https://api.twitter.com/1/"+api_name+"/ids.json?cursor=-1&user_id="+user_id);
    if(null!=json.load("https://api.twitter.com/1/"+api_name+"/ids.json?cursor=-1&user_id="+user_id)){
      return JSON.trimArc(json.get("ids"),new char[]{'[',']'}).split(",");
    }
    return null;
  }
  public String screen_name2id(String screen_name){
    String id = cache_screen_name_id.get(screen_name);
    if(id!=null){
      return id;
    }
    id = lookup("screen_name="+screen_name,"id");
    if(id!=null){
      addCache(id,screen_name);
    }
    return id==null?screen_name:id;
  }
  public String id2screen_name(String id){
    String screen_name = cache_id_screen_name.get(id);
    if(screen_name != null){
      return screen_name;
    }
    screen_name = lookup("user_id="+id,"screen_name");
    if(screen_name != null){
      addCache(id,screen_name);
    }
    return screen_name==null?id:screen_name;
  }
  public String lookup(String filter_str,String key_str){
    JSON user = new JSON();
    api_req_count++;
    try{Thread.sleep(10);}catch(InterruptedException e){}
println("getting - "+"https://api.twitter.com/1/users/lookup.json?include_entities=true&"+filter_str);
    if(null!=user.load("https://api.twitter.com/1/users/lookup.json?"+filter_str)){
      return user.get(key_str);
    }
    return null;
  }
}